conforms file names to consistant standard

scripts/projectiles/explosive_projectile.gd

@@ -0,0 +1,71 @@
+class_name ExplosiveProjectile
+extends Projectile
+
+@export var explosion_range: float = 3.0
+
+var exploded: bool = false
+var sound_done: bool = false
+var particles_done: bool = false
+
+
+func _process(delta: float) -> void:
+	super._process(delta)
+	if !exploded and time_alive >= lifetime:
+		explode()
+
+
+func _on_body_entered(_body: Node) -> void:
+	explode()
+
+
+func explode() -> void:
+	if is_multiplayer_authority() and !exploded:
+		freeze = true
+		exploded = true
+		$CollisionShape3D.call_deferred("set_disabled", true)
+		for enemy: EnemyController in get_tree().get_nodes_in_group("Enemies"):
+			if global_position.distance_to(enemy.global_position) <= explosion_range:
+				hit(enemy)
+				networked_hit.rpc(get_tree().root.get_path_to(enemy))
+		networked_kill.rpc()
+		$Sprite3D.set_visible(false)
+		$GPUParticles3D.emitting = true
+		$AudioStreamPlayer.play()
+
+
+func hit(target: CharacterBody3D) -> void:
+	target.apply_effect(effect)
+	#if owner_id == 0:
+		#if Data.preferences.display_tower_damage_indicators:
+			#spawn_damage_indicator(target.d_n.global_position)
+	#if owner_id == multiplayer.get_unique_id():
+		#if Data.preferences.display_self_damage_indicators:
+			#spawn_damage_indicator(target.d_n.global_position)
+	#if owner_id != 0 and owner_id != multiplayer.get_unique_id():
+		#if Data.preferences.display_party_damage_indicators:
+			#spawn_damage_indicator(target.d_n.global_position)
+
+
+@rpc("reliable")
+func networked_hit(target_node_path: String) -> void:
+	var target: CharacterBody3D = get_tree().root.get_node(target_node_path)
+	hit(target)
+
+
+@rpc("reliable")
+func networked_kill() -> void:
+	$Sprite3D.set_visible(false)
+	$GPUParticles3D.emitting = true
+	$AudioStreamPlayer.play()
+
+
+func _on_audio_stream_player_finished() -> void:
+	sound_done = true
+	if sound_done and particles_done:
+		queue_free()
+
+
+func _on_gpu_particles_3d_finished() -> void:
+	particles_done = true
+	if sound_done and particles_done:
+		queue_free()

scripts/projectiles/explosive_projectile.gd.uid

@@ -0,0 +1 @@
+uid://cubn2iabwg3

scripts/projectiles/homing_projectile.gd

@@ -0,0 +1,18 @@
+class_name HomingProjectile
+extends ExplosiveProjectile
+
+var target: Node3D
+var acceleration: float = 50.0
+var max_speed: float = 13.0
+
+
+func _physics_process(_delta: float) -> void:
+	if is_instance_valid(target):
+		direction = global_position.direction_to(target.global_position)
+		#apply_central_force(direction * acceleration)
+
+
+func _integrate_forces(state: PhysicsDirectBodyState3D) -> void:
+	state.linear_velocity = state.linear_velocity.limit_length(state.linear_velocity.length() * (1.0 - 0.08))
+	state.linear_velocity += direction * acceleration * state.step
+	state.linear_velocity = state.linear_velocity.limit_length(max_speed)

scripts/projectiles/homing_projectile.gd.uid

@@ -0,0 +1 @@
+uid://dwr38fukjqu7r

scripts/projectiles/projectile.gd

@@ -0,0 +1,29 @@
+class_name Projectile
+extends RigidBody3D
+
+@export var collision_shape: CollisionShape3D
+
+var owner_id: int = 0 #should be left unchanged by towers, 1 for host, peer_id on peers
+var direction: Vector3 = Vector3.FORWARD
+var force: float = 2.0
+var damage: float = 0.0
+var lifetime: float = 10.0
+var time_alive: float = 0.0
+var effect: Effect
+
+
+func _ready() -> void:
+	apply_central_impulse(direction * force)
+
+
+func _process(delta: float) -> void:
+	time_alive += delta
+
+
+func _on_body_entered(_body: Node) -> void:
+	pass # Replace with function body.
+
+
+@rpc("reliable")
+func networked_kill() -> void:
+	queue_free()

scripts/projectiles/projectile.gd.uid

@@ -0,0 +1 @@
+uid://bifvnevs5y4nj

scripts/projectiles/status_applying_projectile.gd

@@ -0,0 +1,15 @@
+class_name StatusApplyingProjectile
+extends ExplosiveProjectile
+
+@export var status_stats: StatusStats
+
+
+func hit(target: CharacterBody3D) -> void:
+	super.hit(target)
+	target.status_manager.add_effect(build_status_object())
+
+
+func build_status_object() -> StatusEffect:
+	var status: StatusEffect = StatusEffect.new()
+	status.stats = status_stats
+	return status

scripts/projectiles/status_applying_projectile.gd.uid

@@ -0,0 +1 @@
+uid://ba2aqn82wo747